汇编语言(王爽)-int指令

发表于 | 更新于 | 分类于

一种重要的内中断，由int指令引发的中断

int指令

格式： int n，n为中断类型码

功能：引发中断过程

CPU执行int n指令，相当于引发一个n号中断的中断过程

中断过程如下：

  1. 取中断类型码n

  2. 标志寄存器入栈，TF=0，IF=0

  3. CS、IP入栈

  4. (IP)=(n*4)，(CS)=(n*4+2)

可以在程序中使用int指令调用任何一个中断的中断处理程序

int指令的最终功能和call指令相似，都是调用一段程序

系统将一些具有一定功能的子程序，以中断处理程序的方式提供给应用程序调用。可以使用int指令调用这些子程序

中断处理程序简称为中断例程

编写供应用程序调用的中断例程

编写、安装中断7ch的中断例程

功能：求一word型数据的平方

参数：(ax)=要计算的数据

返回值：dx、ax中存放结果的高16位和低16位

应用举例：求2*3456^2

1
2
3
4
5
6
7
8
9
10
11
12
assume cs:code
code segment

start:	mov ax,3456
	int 7ch		;调用中断7ch的中断例程，计算ax中数据的平方
	add ax,ax
	adc dx,dx		;dx:ax存放结果，将结果乘以2
	mov ax,4c00h
	int 21h
    
code ends
end start

安装程序：

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
assume cs:code
code segment

start:	mov ax,cs
	mov ds,ax		
	mov si,offset sqr			;ds:si指向源地址
	mov ax,0
	mov es,ax		
	mov di,200h				;es:di指向目的地址
	mov cx,offset sqrend-offset sqr		;cx为传输长度
	cld					;正向传输
	rep movsb				;串传送

	mov ax,0				;设置中断向量
	mov es,ax
	mov word ptr es:[7ch*4],200h
	mov word ptr es:[7ch*4+2],0
    
	mov ax,4c00h
	int 21h

sqr:	mul ax					;7ch程序
	iret					;恢复现场
    
sqrend:	nop

code ends
end strart

编写、安装中断7ch的中断例程

功能：将一个全是字母，以0结尾的字符串，转化为大写

参数：ds:si指向字符串的首地址

应用举例：将data段中的字符串转化为大写

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
assume cs:code

data segment
	db 'conversation',0
data ends

code segment
start:	mov ax,data
	mov ds,ax
	mov si,0		;ds:si指向字符串首字母
	int 7ch			;调用中断7ch的中断例程
	
	mov ax,4c00h
	int 21h
code ends
end start

安装程序：

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
assume cs:code
code segment

start:	mov ax,cs
	mov ds,ax
	mov si,offset capital				;ds:si指向源地址
	mov ax,0
	mov es,ax
	mov di,200h					;es:di指向目的地址
	mov cx,offset capitalend-offset capital		# cx为传输长度
	cld						;正向传输
	rep movsb					;串传输
    
	mov ax,0					;设置中断向量
	mov es,ax
	mov word ptr es:[7ch*4],200h
	mov word ptr es:[7ch*4+2],0
	mov ax,4c00h
	int 21h
    
capital:push cx		
	push si						;保存所用寄存器的原始数据
 change:mov cl,[si]
 	mov ch,0
	jcxz ok
	and byte ptr [si],11011111b			;转大写
	inc si
	jmp short change
    ok:	pop si
	pop cx						;恢复所用寄存器原始数据
	iret						;恢复现场

capitalend:nop

code ends
end start

对int、iret和栈的深入理解

用7ch中断例程完成loop指令的功能

loop s执行需要两个信息：循环次数和到s的位移

用cx存放循环次数，bx存放位移

应用举例：在屏幕中间显示80个‘！’

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
assume cs:code
code segment

start:	mov ax,0b800h
	mov es,ax
	mov di,160*12

	mov bx,offset s-offset se		;从标号se到标号s的转移位移
	mov cx,80
  s:	mov byte ptr es:[di],'!'		;显示‘!’
	add di,2
	int 7ch					;调用中断7ch的中断例程，loop功能
    
  se:	nop

	mov ax,4c00h
	int 21h
    
code ends
end start

7ch的中断例程：

1
2
3
4
5
6
7
lp:	push bp			;保存bp寄存器原值
	mov bp,sp		;bp中保存栈顶的偏移地址
	dec cx			;cx自减1
	jcxz lpret		;(cx)=0，则转移，不实现loop s功能
	add [bp+2],bx		;栈中se的偏移地址变为s的偏移地址
lpret:	pop bp			;恢复bp寄存器原值
	iret			;恢复现场时IP值为s的偏移地址，实现loop转移

在中断过程中，当前标志寄存器、CS、IP入栈，此时CS为标号s的段地址，IP为标号se的偏移地址。中断例程中，需将CS设置为标号s的段地址，IP设置为标号s的偏移地址，实现loop s的功能

中断例程中使用到栈，当执行push bp后，栈中情况为：自上而下为bp原值、se的偏移地址(IP)、s的段地址(CS)、标志寄存器原值。即((ss)*16+(bp)+2)处为se的偏移地址(原始IP的值)，将其加上bx中存储的转移位移即变为s的偏移地址(修改了原始IP的值)，再通过iret恢复现场将CS、IP恢复即实现了loop s

BIOS和DOS所提供的中断例程

在系统主板的ROM中存放着一套程序，称为BIOS(基本输入输出系统)

BIOS主要功能：

  1. 硬件系统的检测和初始化程序

  2. 外部中断和内部中断的中断例程

  3. 用于对硬件设备进行I/O操作的中断例程

  4. 其他和硬件系统相关的中断例程

从操作系统的角度来看，DOS的中断例程就是操作系统向程序员提供的编程资源

BIOS和DOS在所提供的中断例程中包含了许多子程序，这些子程序实现了程序员在编程的时候经常需要用到的功能

程序员在编程的时候，可以直接用int指令调用BIOS和DOS提供的中断例程

和硬件设备相关的DOS中断例程中，一般调用了BIOS的中断例程

BIOS和DOS中断例程的安装过程

  1. 开机后，CPU一加电，初始化(CS)=0FFFFH，(IP)=0，自动从FFFF:0单元开始执行程序

    FFFF:0处有一条转跳指令，CPU执行该指令后，转去执行BIOS中的硬件系统检测和初始化程序

  2. 初始化程序将建立BIOS所支持的中断向量，即将BIOS提供的中断例程的入口地址登记在中断向量表中

    对于BIOS所提供的中断例程，只需将入口地址登记在中断向量表中即可，因其是固化到ROM中的程序，一直在内存中存在

  3. 硬件系统检测和初始化完成后，调用int 19h进行操作系统的引导。从此将计算机交由操作系统控制

  4. DOS启动后，除完成其他工作外，还将它所提供的中断例程装入内存，并建立相应的中断向量

BIOS中断例程应用

int 10h中断例程是BIOS提供的中断例程，其中包含了多个和屏幕输出相关的子程序

一般来说，一个供程序员调用的中断例程中往往包含多个子程序，中断例程内部用传递进来的参数来决定执行哪一个子程序

BIOS和DOS提供的中断例程，都用ah来传递内部子程序的编号

int 10h中断例程的设置光标位置功能

1
2
3
4
5
mov ah,2		;置光标
mov bh,0		;第0页
mov dh,5		;dh中存储行号
mov dl,12		;dl中放列号
int 10h

(ah)=2表示调用第10h号中断例程的2号子程序，功能为设置光标位置，可提供光标所在行号(80*25字符模式下:0–24)、列号(80*25字符模式下:0–79)和页号作为参数

(bh)=0、(dh)=5、(dl)=12，设置光标到第0页，第5行，第12列

bh中页号的含义：在内存地址空间中，B8000H-BFFFFH共32KB的空间，为80*25彩色字符模式的显示缓冲区。一屏的内容在显示缓冲区中共占4000个字节

显示缓冲区分为8页，每页4KB，显示器可以显示任意一页的内容。一般情况下，显示第0页的内容。即通常情况下，B8000H-B8F9FH中的4000个字节的内容将显示在显示屏上

int 10h中断例程的在光标位置显示字符功能

1
2
3
4
5
6
mov ah,9		;在光标位置显示字符
mov al,'a'		;字符
mov bl,7		;颜色属性
mov bh,0		;第0页
mov cx,3		;字符重复个数
int 10h

(ah)=9表示调用第10h号中断例程的9号子程序，功能为在光标位置显示字符，可以提供要显示的字符、颜色属性、页号、字符重复个数作为参数

bl中的颜色属性的格式如下

1.png

编程:在屏幕的5行12列显示3个红底高亮闪烁绿色的’a’

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
assume cs:code
code segment

	mov ah,2		;设置光标
	mov bh,0		;第0页
	mov dh,5		;dh中放行号
	mov dl,12		;dl中放列号
	int 10h
    
	mov ah,9		;在光标位置显示字符
	mov al,'a'		;字符
	mov bl,11001010b	;字符颜色属性
	mov bh,0		;第0页
	mov cx,3		;字符重复个数
	int 10h
    
	mov ax,4c00h
	int 21h

code ends
end

DOS中断例程应用

int 21h中断例程是DOS提供的中断例程，其中包含了DOS提供给程序员在编程时调用的子程序

int 21h中断例程的4ch号功能

一直使用int 21h中断例程的4ch号功能，即程序返回功能

1
2
3
mov ah,4ch		;程序返回
mov al,0		;返回值
int 21h

(ah)=4ch表示调用第21h号中断例程的4ch号子程序，功能为程序返回，可提供返回值作为参数

课程前面使用这个功能时经常写做

1
2
mov ax,4c00h
int 21h

int 21h中断例程在光标位置显示字符串的功能

1
2
3
ds:dx指向字符串		;要显示的字符串需用"$"作为结束符
mov ah,9		;功能号9，表示在光标位置显示字符串
int 21h

(ah)=9表示调用第21h号中断例程的9号子程序，功能为在光标位置显示字符串，可以提供要显示字符串的地址作为参数

编程:在屏幕的5行12列显示字符串”Welcome to masm!”

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
assume cs:code

data segment
	db 'Welcome to masm!','$'	;$不显示，起边界作用
data ends

code segment
start:	mov ah,2			;置光标
	mov bh,0			;第0页
	mov dh,5			;dh中放行号
	mov dl,12			;dl中放列号
	int 10h				;执行BIOS第10h号中断例程的2号子程序
    
	mov ax,data
	mov ds,ax
	mov dx,0			;ds:dx指向字符串首地址
	mov ah,9
	int 21h				;执行DOS第21h号中断例程的9号子程序
    
	mov ax,4c00h
	int 21h
    
code ends
end start

DOS为程序员提供了许多可以调用的子程序，都包含在int 21h中断例程中

---------------The End---------------
0%